Gewächshauspumpe 12V mit Timer steuern - 2 Relais aktiv

Wenn ein Gewächshaus eine PV mit 12V Auto-Akku im Zugriff hat, dann ist eine automatische Pumpensteuerung nicht weit.

(mit Hotspot am Handy für Einstellungen reicht das - sonst ohne WLAN).

Bisher habe ich das mit dem folgenden Code auch für einen 2tägigen Betrieb aktiv laufen. Nun möchte ich aber das 2. Relais (bisher ungenutzt) mit nutzen. Da der Sheduler beim 2tägigen Betrieb (Schaltung erfolgt durch Abschalten des gesamten Shedulers) dann auch das Relais 2 abschalten würde, muss umgebaut werden.

Aktuell habe ich noch keine Idee wie ich einzelne Timer (z.B. Relais1 Timer1-10, und Relais Timer11-16) "enable" schalten könnte!

Timer1 0 - schaltet diesen zwar schön ab, aber dann ist alles weg ! - das ist keine Lösung

Hat jemand was für mich oder habe ich sogar einen Befehl übersehen?

template {"NAME":"LC-ESP01-2R-12V<p>Counter2=Summe<p>Counter3=Boot","GPIO":[0,3200,0,3232,353,354,0,0,224,225,226,227,352,0],"FLAG":0,"BASE":18}

rule1
ON System#boot do backlog time 1587435620; Power1 0; Var1 0; Webcolor1 FF007F endon
on Wifi#Connected do Backlog time 0; ___autosync___; Webcolor1 66ff66 endon
on INFO3#bootcount do Backlog counter3 %value% endon
on Time#Initialized do Webcolor1 66ff66 endon

Rule2
on Power1#Boot do Backlog Baudrate 115200; SerialSend5 0 endon
on Power1#State=1 do Backlog SerialSend5 A00101A2; counter2+1 endon
on Power1#State=0 do SerialSend5 A00100A1 endon
on Power2#State=1 do SerialSend5 A00201A3 endon
on Power2#State=0 do SerialSend5 A00200A2 endon
on VAR1#State>0 do backlog __2taeglich_; Timers 2 endon
on VAR1#State=0 do backlog __taeglich__; Timers 1 endon

Rule3
on Power4#State=1 do Timers 1 endon
on Power4#State=0 do Timers 0 endon
on Power3#State=1 do VAR1 1 endon
on Power3#State=0 do VAR1 0 endon
on Time#Minute=2 do MULT1 1 endon

backlog Webbutton1 manuell<p>Pumpe; Webbutton2 Relais2; Webbutton3 2tägig<p>Pumpe
backlog Webbutton4 <a href="/tm?"style="color:black">Timer</a>-Link

Erklärung:
SetOption36 20 - 20 Boots zulassen bis RESET-Firmware in 10 s
counter1 - offen
counter2 - Summe Schaltungen
counter3 - Bootanzahl

PS: geht nur wenn Release Tasmota kleiner 13.3.0.5 !

ja

aber wie in der Rule? wenn ich den aktuellen Inhalt des Timers nicht kenne.

Ziel könnte sein:

Var1#state=1 on Timer1 enable 1 endon

ja - ohne richtiges on do endon - war übers Handy schnell hingeworfen

super, danke

genau diese von dir reflektierte Syntax konnte ich nicht herauslesen - es funzt

So sieht jetzt die Lösung aus.

Timer 1-4 kann einen Tag pausiert werden und Termine (Ausschalten oder für Relais2) auf den weiteren 5-16 laufen durchgängig.

Nach der Tagespause wird automatisch auf täglich geschalten.

rule1
ON System#boot do backlog time 1587435620; Power1 0; Var1 0; Webcolor1 FF007F endon
on Wifi#Connected do Backlog time 0; ___autosync___; Webcolor1 66ff66 endon
on INFO3#bootcount do Backlog counter3 %value% endon
on Time#Initialized do Webcolor1 66ff66 endon


Rule2
on Power1#Boot do Backlog Baudrate 115200; SerialSend5 0 endon
on Power1#State=1 do Backlog SerialSend5 A00101A2; counter2+1 endon
on Power1#State=0 do SerialSend5 A00100A1 endon
on Power2#State=1 do SerialSend5 A00201A3 endon
on Power2#State=0 do SerialSend5 A00200A2 endon
on VAR1#state>0 do backlog __taeglich_; timer1 {"enable":1}; timer2 {"enable":1}; timer3 {"enable":1}; timer4 {"enable":1} endon
on VAR1#state=-1 do backlog __2taeglich_; timer1 {"enable":0}; timer2 {"enable":0}; timer3 {"enable":0}; timer4 {"enable":0} endon
on VAR1#state=0 do Power3 0 endon


Rule3
on Power4#State=1 do Timers 1 endon
on Power4#State=0 do Timers 0 endon
on Power3#State=1 do VAR1 -1 endon
on Power3#State=0 do VAR1 1 endon
on Time#Minute=2 do ADD1 1 endon



backlog Webbutton1 manuell<p>Pumpe; Webbutton2 Relais2; Webbutton3 2tägig<p>Timer1-4
backlog Webbutton4 <a href="/tm?"style="color:black">Timer</a>-Link 

habe das 2 Kanal Modul im Testeinsatz seit 2 Wochen und leider kurzzeitig fehlerhaft mit +/- ( vertauscht) belegt - der zentrale 5 V Spannungswandler (L78M05) war gleich durch 😕

https://www.amazon.de/gp/aw/d/B008C1…ob_b_asin_title - hat mir neue gebracht und nach dem Wechsel geht es jetzt weiter ( nun aber mit einer 1A Sicherheitsdiode gegen Vertauschung im wilden Feldeinsatz)

Habe dann noch gleich nach dem Löten aus der aktuellen Wetterlage (2024 La Nina) die dynamische manuelle Lauflängenanpassung mit einem Slider für die Oberfläche organisiert (mult10 0.1 um nur 10 Minuten Dynamik zu ermöglichen).

template {"NAME":"Counter1=HH:mm<p>Counter2=SummeR1 E/A<p>Counter3=Boot","GPIO":[0,3200,416,3232,353,354,0,0,224,225,226,227,352,0],"FLAG":0,"BASE":18}

Backlog Latitude 51.785783; Longitude 14.417215; timezone 99; webtime 0 19; CalcRes 0; SetOption36 20 
Backlog NTPServer1 192.168.178.1; NTPServer2 172.20.10.1; NTPServer3 3.de.pool.ntp.org; Sleep 250, Wifipower15
Backlog devicename <h6>Ausschalten bei Minute 10-20 (so wie Counter1 anzeigt)

Rule1
ON System#Init do backlog time 1587435620; Power1 0; Var1 0; Webcolor1 FF007F; VAR12 0 endon
on System#Boot do Backlog time 0; ___autosync___; Webcolor1 66ff66 endon
on Wifi#Connected do Backlog time 0; __wifi___; Webcolor1 66ff66 endon
on INFO3#bootcount do Backlog counter3 %value% endon
on Time#Initialized do Webcolor1 66ff66 endon
on VAR2#State==-1 do VAR1 1 endon
on VAR2#State==0 do Backlog VAR1 0; VAR2 -3 endon
on VAR5#state$|%VAR11% do Power1 %VAR12% endon

Rule2
on Power1#Boot do Backlog Baudrate 115200; SerialSend5 0 endon
on Power1#State=1 do Backlog SerialSend5 A00101A2; counter2+1; time 0; Webcolor1 66ff66 endon
on Power1#State=0 do SerialSend5 A00100A1 endon
on Power2#State=1 do SerialSend5 A00201A3 endon
on Power2#State=0 do SerialSend5 A00200A2 endon
on VAR1#state>0 do backlog timer1 {"enable":1}; timer2 {"enable":1}; timer3 {"enable":1}; timer4 {"enable":1} endon
on VAR1#state=0 do backlog timer1 {"enable":0}; timer2 {"enable":0}; timer3 {"enable":0}; timer4 {"enable":0} endon
on VAR3#state do Backlog counter1 %VAR3% endon
on VAR10#state do counter1 %VAR10% endon

Rule3
on Power5#State=1 do VAR12 0 endon
on Power5#State=0 do VAR12 A endon
on Power4#State=1 do Timers 1 endon
on Power4#State=0 do Timers 0 endon
on Power3#State=1 do backlog VAR1 0; VAR2 -3 endon
on Power3#State=0 do backlog VAR1 1; VAR2 1 endon
on Time#Minute=2 do Backlog ADD1 1; ADD2 1; VAR3 %VAR2%; MULT3 -1 endon
on Dimmer#state do backlog var10 %value%; mult10 0.1; ADD10 10 endon
on time#minute|1 do Backlog VAR11 :%VAR10%:; VAR5 %timestamp% endon

backlog Webbutton1 manuell Pumpe<hr>Timesync; Webbutton2 Relais2; Webbutton3 2tägig<p>Timer1-4; Webbutton5 HH:mm <p> Minute AUS
backlog Webbutton4 <a href="/tm?"style="color:black">Timer</a>-Link

Erklärung:
SetOption36 20 - 20 Boots zulassen bis RESET-Firmware in 10 s
counter1 - Ausschaltminute (Dynamik zur festen Timer hh:10 - hh:20 möglich)
counter2 - Summe Schaltungen
counter3 - Bootanzahl